home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Run Magazine ReRun 1986 January & February
/
rerun-1986-01-02.d64
/
autorun 64
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-09-20
|
817b
|
29 lines
10 printchr$(147)chr$(18)"auto-run converter"
20 s=0:fori=828to862:readv:pokei,v:s=s+v:nexti:ifs=3677then40
30 print"error in data":end
40 print"insert program disk"
50 input"program name";f1$
60 close4:close5:close15:open15,8,15,"i":close15:open15,8,15
70 open4,8,4,"0:"+f1$+",p,r":gosub230:ifer<>0thenclose4:goto50
80 input"output name";f1$
90 open5,8,5,"0:"+f1$+",p,w":gosub230:ifer<>0thenclose5:goto80
100 z$=chr$(0)
110 poke829,peek(770):poke834,peek(771):poke857,peek(771)
120 printchr$(147)"wait"
130 get#4,a$:get#4,b$:l=asc(a$+z$)+256*asc(b$+z$)-1
140 print#5,chr$(2)chr$(3)chr$(60)chr$(3);
150 c$="run"+chr$(0)
160 fori=1tolen(c$):poke858+i,asc(mid$(c$,i,1)):nexti
170 fori=772tol:print#5,chr$(peek(i));:nexti
180 print"copying file"
190 get#4,a$:s=st:print#5,chr$(asc(a$+z$));:ifs=0then190
200 gosub230
210 close4:close5:close15
220 printe1$:print"done":end
230 input#15,er,e1$,t,s:ifer=0thenreturn
240 printe1$;t;s:return
250 data169,131,141,2,3,169,196,141,3,3
260 data160,0,185,91,3,153,0,2,240,3
270 data200,208,245,162,255,160,1,76,134,196
280 data0,82,85,78,0